feedgnuplot/completions/zsh/_feedgnuplot

#compdef feedgnuplot

_arguments -S                                                                     \
    '()--domain[first element of each line is the domain variable]'               \
    '--dataid[each data point is preceded by the corresponding ID]'               \
    '(--monotonic --xlen --histogram)--3d'                                        \
    '--colormap[show a colormapped xy plot]'                                      \
    '--stream[Plot the data in realtime]::period in s:'                           \
    '--lines'                                                                     \
    '--points'                                                                    \
    '--circles'                                                                   \
    '--xlabel:X-axis label:'                                                      \
    '--x2label:X2-axis label:'                                                    \
    '--ylabel:Y-axis label:'                                                      \
    '--y2label:Y2-axis label:'                                                    \
    '--zlabel:Z-axis label:'                                                      \
    '--title:Plot title:'                                                         \
    '--autolegend[Label each plot with its data ID]'                              \
    '(--3d)--xlen[the size of the x-window to plot]:window size:'                 \
    '(--xlen)--xmin:min X:'                                                       \
    '(--xlen)--xmax:max X:'                                                       \
    '--x2min:min X2:'                                                             \
    '--x2max:max X2:'                                                             \
    '--ymin:min Y:'                                                               \
    '--ymax:max Y:'                                                               \
    '--y2min:min Y2:'                                                             \
    '--y2max:max Y2:'                                                             \
    '--zmin:min Z:'                                                               \
    '--zmax:max Z:'                                                               \
    '*--x2:curve to place on the X2Y1 axis:'                                      \
    '*--y2:curve to place on the X1Y2 axis:'                                      \
    '*--x2y1:curve to place on the X2Y1 axis:'                                    \
    '*--x1y2:curve to place on the X1Y2 axis:'                                    \
    '*--x2y2:curve to place on the X2Y2 axis:'                                    \
    '(--with)--curvestyleall[Additional styles for ALL curves]:style'             \
    '(--with)--styleall[Additional styles for ALL curves]:style'                  \
    '(--curvestyleall)--with[Additional styles for ALL curves]:style'             \
    '*--extracmds[Additional gnuplot commands]:command'                           \
    '*--set[Additional 'set' gnuplot commands]:set-option'                        \
    '*--unset[Additional 'unset' gnuplot commands]:unset-option'                  \
    '*--equation[Raw symbolic equation]:equation'                                 \
    '*--equation-below[Raw symbolic equation]:equation'                           \
    '*--equation-above[Raw symbolic equation to plot on top]:equation'            \
    '--image[Image file to render beneath the data]:image:_files -g "(#i)*.(jpg|jpeg|png|gif)"' \
    '--square[Plot data with square aspect ratio]'                                \
    '--square-xy[For 3D plots, set square aspect ratio for ONLY the x,y axes]'    \
    '--hardcopy[Plot to a file]:new image filename:_files -g "(#i)*.(jpg|jpeg|png|gif)"' \
    '--maxcurves[The maximum allowed number of curves]:number of curves'          \
    '(--3d)--monotonic[Resets plot if an X in the past is seen]'                  \
    '(--rangesizeall)--extraValuesPerPoint[How many extra values are given for each data range]:N'\
    '(--extraValuesPerPoint)--rangesizeall[How many values are given for each data range]:N'\
    '*--rangesize[How many values comprise a data range in this curve]:curve id: :N:' \
    '(--extraValuesPerPoint)--tuplesizeall[How many values are given for each data tuple]:N'\
    '*--tuplesize[How many values comprise a data tuple in this curve]:curve id: :N:' \
    '--dump[Instead of printing to gnuplot, print to STDOUT]'                     \
    '--geometry[The X11 geometry string]:geometry string:'                        \
    '*--curvestyle[Additional styles for a curve]:curve id: :style:'              \
    '*--style[Additional styles for a curve]:curve id: :style:'                   \
    '*--every[Decimation factor for a curve]:curve id: :decimation factor:'       \
    '--everyall[Decimation factor for ALL curves]:decimation factor'              \
    '*--using[Column specification for a curve]:curve id: :column specification:' \
    '--usingall[Column specification ALL curves]:column specification'            \
    '(--3d)*--histogram:plot to treat as a histogram:'                            \
    '--binwidth:Histogram bin width:'                                             \
    '--histstyle:Style of histogram:(frequency fnormal unique cumulative cnormal)' \
    '--terminal:Terminal options to set with "set terminal":'                     \
    '*--legend[Legend for a curve]:curve id: :legend:'                            \
    '--exit[Exit gnuplot after making the plot]'                                  \
    '--version'                                                                   \
    '--help'                                                                      \
    '--timefmt[Format for time/date data]:time format'                            \
    '--xticlabels[x-axis tic labels are read from the data]'                      \
    '--vnlog[column IDs come from a vnlog header]'