dnl $Id$
dnl
dnl
dnl Exported and configured variables:
dnl CFLAGS
dnl LDFLAGS
dnl INCLUDES


dnl ------------------------------------------------------------------
dnl Initialization for autoconf
dnl ------------------------------------------------------------------
AC_PREREQ(2.59)
AC_INIT
AC_CONFIG_SRCDIR([lib/lbfgs.c])


dnl ------------------------------------------------------------------
dnl Initialization for automake
dnl ------------------------------------------------------------------
AM_INIT_AUTOMAKE(liblbfgs, 1.4)
AC_CONFIG_HEADERS(config.h)
AM_MAINTAINER_MODE


dnl ------------------------------------------------------------------
dnl Checks for program
dnl ------------------------------------------------------------------
AC_PROG_LIBTOOL
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET


dnl ------------------------------------------------------------------
dnl Initialization for variables
dnl ------------------------------------------------------------------
CFLAGS="${ac_save_CFLAGS}"
LDFLAGS="${ac_save_LDFLAGS}"
INCLUDES="-I\$(top_srcdir) -I\$(top_srcdir)/include"


dnl ------------------------------------------------------------------
dnl Checks for header files.
dnl ------------------------------------------------------------------
AC_HEADER_STDC
AC_CHECK_HEADERS(xmmintrin.h emmintrin.h)


dnl ------------------------------------------------------------------
dnl Checks for debugging mode
dnl ------------------------------------------------------------------
AC_ARG_ENABLE(
  debug,
  [AS_HELP_STRING([--enable-debug],[Turn on debugging])]
)

if test "x$enable_debug" = "xyes"; then
   CFLAGS="-DDEBUG -O -g ${CFLAGS}"
else
   CFLAGS="-O3 -ffast-math ${CFLAGS}"
fi

dnl ------------------------------------------------------------------
dnl Checks for profiling mode
dnl ------------------------------------------------------------------
AC_ARG_ENABLE(
  profile,
  [AS_HELP_STRING([--enable-profile],[Turn on profiling])]
)

if test "x$enable_profile" = "xyes"; then
   CFLAGS="-DPROFILE -pg ${CFLAGS}"
fi


dnl ------------------------------------------------------------------
dnl Checks for SSE build
dnl ------------------------------------------------------------------
AC_ARG_ENABLE(
  sse,
  [AS_HELP_STRING([--enable-sse],[Enable SSE optimized routines])]
)

if test "x$enable_sse" = "xyes"; then
   CFLAGS="-msse2 -DUSE_SSE ${CFLAGS}"
fi


dnl ------------------------------------------------------------------
dnl Checks for library functions.
dnl ------------------------------------------------------------------
AC_CHECK_LIB(m, fabs)

dnl ------------------------------------------------------------------
dnl Export variables
dnl ------------------------------------------------------------------
AC_SUBST(CFLAGS)
AC_SUBST(LDFLAGS)
AC_SUBST(INCLUDES)

dnl ------------------------------------------------------------------
dnl Output the configure results.
dnl ------------------------------------------------------------------
AC_CONFIG_FILES(Makefile)
AC_OUTPUT